Windows 10 Build 1904x 完美移除 Chromium Edge 方案
本帖最后由 fhuurgbj 于 2025-2-14 11:45 编辑自己总结的移除方案
测试如下：19041.1 安装 2025.01 累积更新，使用方案移除 Chromium Edge，在此基础上安装 2025.02 累积更新，更新成功且 Edge 并未重新安装。并且不影响组件存储完整性 (DISM /ScanHealth 和 sfc /scannow 一切正常)。
使用方法：复制代码内容至记事本，保存为 cmd 文件，运行前手动定义 Mount 映像挂载路径后以管理员身份运行脚本即可。
现将自用方案放出，仅用于离线挂载的映像。还请坛友们一起测试，有问题及时反馈。
2025.02.14 已更新脚本代码，感谢 @wcb0414
@echo off
set "Mount=D:\Mount"
call :WORK 2>nul
pause
exit /b
:WORK
if not exist "%Mount%\Windows\explorer.exe" exit /b
reg query "HKU\S-1-5-19" >nul 2>nul || exit /b
set "E1=x86_microsoft-windows-edgechromium_31bf3856ad364e35_10.0.19041.3636_none_181897eb58d04a07"
set "E2=x86_microsoft-windows-edgechromium_31bf3856ad364e35_none_83204c2f0ca4ce9b"
if exist "%Mount%\Windows\SysWOW64" (
set "E1=amd64_microsoft-windows-edgechromium_31bf3856ad364e35_10.0.19041.3636_none_7437336f112dbb3d"
set "E2=amd64_microsoft-windows-edgechromium_31bf3856ad364e35_none_df3ee7b2c5023fd1"
)
set "F1=%Mount%\Windows\WinSxS\%E1%"
set "F2=%Mount%\Windows\WinSxS\Manifests\%E1%.manifest"
if exist "%Mount%\Program Files (x86)\Microsoft\Edge*" rd /s /q "%Mount%\Program Files (x86)\Microsoft"
if exist "%Mount%\Program Files\Microsoft\Edge*" rd /s /q "%Mount%\Program Files\Microsoft"
takeown /F "%F1%" && cacls "%F1%" /E /G %USERNAME%:F && rd /s /q "%F1%"
takeown /F "%F2%" && cacls "%F2%" /E /G %USERNAME%:F && del /f /q "%F2%"
reg load HKLM\TK_COMPONENTS "%Mount%\Windows\System32\config\COMPONENTS"
reg load HKLM\TK_SOFTWARE "%Mount%\Windows\System32\config\SOFTWARE"
reg load HKLM\TK_SYSTEM "%Mount%\Windows\System32\config\SYSTEM"
reg delete "HKLM\TK_COMPONENTS\DerivedData\Components\%E1%" /f
reg delete "HKLM\TK_SOFTWARE\Microsoft\Windows\CurrentVersion\SideBySide\Winners\%E2%" /f
reg delete "HKLM\TK_SOFTWARE\Microsoft\Active Setup\Installed Components\{9459C573-B17A-45AE-9F64-1857B5D58CEE}" /f
reg delete "HKLM\TK_SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\MicrosoftEdgeUpdate.exe" /f
reg delete "HKLM\TK_SYSTEM\ControlSet001\Services\edgeupdate" /f
reg delete "HKLM\TK_SYSTEM\ControlSet001\Services\edgeupdatem" /f
if exist "%Mount%\Windows\SysWOW64" (
reg delete "HKLM\TK_SOFTWARE\WOW6432Node\Microsoft\EdgeUpdate" /f
reg delete "HKLM\TK_SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Uninstall\Microsoft Edge" /f
reg delete "HKLM\TK_SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Uninstall\Microsoft Edge Update" /f
@REM reg delete "HKLM\TK_SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Uninstall\Microsoft EdgeWebView" /f
) else (
reg delete "HKLM\TK_SOFTWARE\Microsoft\EdgeUpdate" /f
reg delete "HKLM\TK_SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Microsoft Edge" /f
reg delete "HKLM\TK_SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Microsoft Edge Update" /f
@REM reg delete "HKLM\TK_SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Microsoft EdgeWebView" /f
)
reg unload HKLM\TK_COMPONENTS
reg unload HKLM\TK_SOFTWARE
reg unload HKLM\TK_SYSTEM
goto :eof
谢谢楼主分享！悄悄问一下，superUser64.exe 在哪儿？ snakegao 发表于 2025-2-12 20:54
谢谢楼主分享！悄悄问一下，superUser64.exe 在哪儿？
https://github.com/mspaintmsi/superUser/releases/latest 这个方案试试看。 谢谢楼主分享 感觉这浏览器不是挺好用的嘛 使用第三方组件优化工具
不是能精简这个垃圾浏览器吗？
感觉跟我使用习惯不大顺手
反而感觉360极速浏览器和2345浏览器很不错
对这两个阉割后不装全家桶
简直完美 浪o_O 发表于 2025-2-12 22:25
感觉这浏览器不是挺好用的嘛
的确好用，我自己的主要浏览器也是 Edge。
但是累积更新中的 Edge 一直都是 92 版本的从未更新过，不用的人永远不会用，需要用的人到时候还得更新，能在不破坏组件存储的情况下移除是最好的办法。更新后32 和 64 位的 WinSxS 中各有一个一百多 MB 大小的 Edge.wim，用的 esd (LZMS) 的压缩算法，导致 install.esd 最后压缩后浪费两百多 MB 存储空间 (就是 install.esd 里还嵌套 Edge.wim，该文件没法压缩)。我每个月都是做整合更新镜像自己收藏的，还是希望镜像能干净一些。
Windows 11 Build 26052 之后支持 DISM 直接移除 Edge。还有 EdgeWebViewFoD 也可以直接 DISM 移除，处理起来比 Windows10 要方便不少。因为微软从不通过累积更新来升级 Edge (EdgeWebView FoD 除外)，至少目前是这样。 可以试试Remove-MS-Edge
Remove-Edge.exe仅删除Edge；
Remove-EdgeWeb.exe删除Edge和WebView；
Remove-NoTerm.exe仅删除Edge，静默操作。
项目地址：https://github.com/ShadowWhisperer/Remove-MS-Edge
下载地址：https://heu168.lanzouo.com/b00pn9ief 密码:a8gs fhuurgbj 发表于 2025-2-13 06:18
的确好用，我自己的主要浏览器也是 Edge。
但是累积更新中的 Edge 一直都是 92 版本的从未更新过，不用的 ...
实际从22621开始就支持使用dism移除edge Ragena 发表于 2025-2-13 08:05
可以试试Remove-MS-Edge
Remove-Edge.exe仅删除Edge；
我这个是以移除组件存储 WinSxS 中的 Chromium Edge 为主要目的，这个工具好像只能处理 Program Files 中的吧 感谢分享。之前每次都用dism卸载不不干净。可能我操作方法不当。。 感谢分享 Edge貌似也没那么不堪吧？ edge到处拉文件，系统WebView又不更新，各大软件又自带WebView。真服了。 本帖最后由 wcb0414 于 2025-2-14 10:56 编辑
除了以上内容，注册表还有遗留
HKLM\SOFTWARE\Microsoft\Active Setup\Installed Components\{9459C573-B17A-45AE-9F64-1857B5D58CEE}
HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\MicrosoftEdgeUpdate.exe
HKLM\SOFTWARE\Microsoft\EdgeUpdate
HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Microsoft Edge
HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Microsoft Edge Update
HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Microsoft EdgeWebView
HKLM\SOFTWARE\WOW6432Node\Microsoft\EdgeUpdate
HKLM\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Uninstall\Microsoft Edge
HKLM\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Uninstall\Microsoft Edge Update
HKLM\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Uninstall\Microsoft EdgeWebView
HKLM\SYSTEM\ControlSet001\Services\edgeupdate
HKLM\SYSTEM\ControlSet001\Services\edgeupdatem
除了使用superUser64.exe工具来删除文件，还可以使用takeow和 cacls命令提权删除（优点不需要第三方工具）。
例如：
set "FileName=C:\Windows\WinSxS\Manifests\amd64_microsoft-windows-edgechromium_31bf3856ad364e35_10.0.19041.3636_none_7437336f112dbb3d.manifest"
if exist "%FileName%" (takeown /F "%FileName%" >nul && cacls "%FileName%" /E /G %USERNAME%:F >nul && DEL /F /Q "%FileName%" >nul)
wcb0414 发表于 2025-2-14 10:45
除了以上内容，注册表还有遗留
HKLM\SOFTWARE\Microsoft\Active Setup\Installed Components\{9459C573-B17 ...
感谢补充，脚本已更新 Hanamaru 发表于 2025-2-13 08:30
实际从22621开始就支持使用dism移除edge
感谢指正，已实测 22621 可以 感谢分享~！ 本帖最后由 wcb0414 于 2025-2-14 20:45 编辑
fhuurgbj 发表于 2025-2-14 11:46
感谢补充，脚本已更新takeown /F "%F1%" && cacls "%F1%" /E /G %USERNAME%:F && rd /s /q "%F1%"
需先删除目录中的文件，后才能删除目录